classes

FadeDisplacer.pbk

Stiahnuť FadeDisplacer.pbk

/*
Copyright (c) 2010, Jozef Chúťka
All rights reserved.

Redistribution and use in source and binary forms, with or without
modification, are permitted provided that the following conditions are met:
1. Redistributions of source code must retain the above copyright
   notice, this list of conditions and the following disclaimer.
2. Redistributions in binary form must reproduce the above copyright
   notice, this list of conditions and the following disclaimer in the
   documentation and/or other materials provided with the distribution.
3. All advertising materials mentioning features or use of this software
   must display the following acknowledgement:
   This product includes software developed by the Jozef Chúťka.
4. Neither the name of the Jozef Chúťka nor the
   names of its contributors may be used to endorse or promote products
   derived from this software without specific prior written permission.

THIS SOFTWARE IS PROVIDED BY Jozef Chúťka ''AS IS'' AND ANY
EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
DISCLAIMED. IN NO EVENT SHALL Jozef Chúťka BE LIABLE FOR ANY
DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
(INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
(INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
*/

<languageVersion : 1.0;>

kernel FadeDisplacer
<
	namespace : "sk.yoz";
	vendor : "Yoz";
	version : 1;
	description : "Displacement by bitmap map";
>
{
	input image4 src;
	input image1 map;
	input image4 fader;
	output pixel4 dst;

	parameter float dx
	<
		minValue: float(-1000.0);
		maxValue: float(1000.0);
		defaultValue: float(0.0);
		description: "The amount of displacement on x axis.";
	>;

	parameter float dy
	<
		minValue: float(-1000.0);
		maxValue: float(1000.0);
		defaultValue: float(0.0);
		description: "The amount of displacement on y axis.";
	>;
	
	parameter float fadeNear
	<
		minValue: float(-5.0);
		maxValue: float(5.0);
		defaultValue: float(0.0);
		description: "The amount of fader alpha on near map areas.";
	>;
	
	parameter float fadeDistant
	<
		minValue: float(-5.0);
		maxValue: float(5.0);
		defaultValue: float(0.0);
		description: "The amount of fader alpha on distant map areas.";
	>;
	
	void evaluatePixel()
	{
		float2 pos = outCoord();
		float amount = sampleLinear(map, pos);
		float2 displacedPos = float2(
			pos.x + dx * amount, 
			pos.y + dy * amount);
		dst = sampleLinear(src, displacedPos);
		
		float4 faderData = sampleLinear(fader, displacedPos);
		float fadeAmount = fadeDistant - amount * (fadeDistant - fadeNear);
		float sourceAmount = 1.0 - fadeAmount;
		dst = dst * float4(sourceAmount) + faderData * float4(fadeAmount);
	}
}